重磅｜Stata编程实现『融资约束』 度量的六种方法

青年会计学者联合发起会计领域NO.1高端自媒体

传播会计前辈思想，引领青年一代成长

因缘分相聚，因互助成长，因智慧光华

高级会计专题应用模块即将上演~！

今天，小编要跟各位盟友分享如何使用Stata编程计算融资约束（FC）变量。

自Fazzari（1988）提出投资-现金流敏感性衡量企业融资约束（FC）以来，融资约束逐渐成为公司财务领域的重要话题，与此同时，融资约束的计量模型和衡量方法也是层出不穷，本文主要讨论融资约束计量模型和衡量方法在Stata中的编程实现。对融资约束主题感兴趣的盟友可以先阅读一下相关文献。

本文演示使用的数据均来自国泰安CSMAR数据库，为便于计算，部分变量名直接采用国泰安数据库导出的字段名。Stata编程计算融资约束变量的do文档如下。

/*融资约束变量的计算 原始do文档*/

clear all

cd "D:\stata15\ado\personal\融资约束变量计算"

use "融资约束变量计算.dta" , clear

xtset id year

*===变量定义===*

基本变量定义

gen roa = b002000000/TA // 净利润/总资产

gen roe = b002000000/a003000000 // 净利润/所有者权益合计

replace div_cash = 0 if div_cash ==. //每股税前现金股利

replace f010701b = 0 if f010701b ==. //利息保障倍数

01

Fazzari 1988 投资-现金流敏感性

local fm "L.TA" // 采用期初总资产标准化

*local fm "K" // 也可采用期初固定资产净值标准化

gen cflow= c001000000/`fm' // 经营活动产生的现金流净额/fm

gen cash = c006000000/`fm' // 现金及现金等价物期末余额/fm，或采用货币资金/fm，即a001101000/fm

gen invt = c002006000/`fm' // 购建固定资产、无形资产和其他长期资产支付的现金/fm

gen sale = b001101000/`fm' // 营业收入/fm

gen wcmi = ((a001100000-a002100000)-a001123000)/`fm' //(营运资本-存货净额)/总资产，营运资本=流动资产-流动负债

2

Almeida 2004 现金-现金流敏感

gen choldings = c005000000/TA //现金及现金等价物净增加额/总资产

label var choldings "现金持有的变化"

gen cflow2= c001000000/TA // 经营活动产生的现金流净额/总资产

label var cflow2 "经营性现金流与总资产之比"

3

K&Z 1997 KZ指数

xtset id year

local fm "L.K" // 采用期初固定资产净值标准化

gen kzindex = -1.002*c001000000/`fm' + 0.283*tobin + 3.139*tl ///

 - 39.368*(div_cash*nshrn)/`fm' - 1.315*c006000000/`fm'

// 采用每股现金股利(div_cash) 或者 每股股利(div_ps)

label var kzindex "KZ指数" // Lamont 2001

gen kzindex2 = -6.315*cflow - 39.356*(div_cash*nshrn)/L.TA ///

 - 3.494*c006000000/L.TA + 3.291*tl + 0.460*tobin

label var kzindex2 "KZ指数2" // 魏志华 2014 会计研究

4

W&W 2006 WW指数

gen wwindex = -0.091*c001000000/TA -0.062*div_yes + 0.021*ll ///

 - 0.044*size + 0.102*indsgr -0.035*sgr

label var wwindex "WW指数"

5

H&P 2009 SA指数

gen saindex = 0.043*size^2 - 0.040*firmage - 0.737*size

label var saindex "SA指数"

6

李焰 2008 Q指数

local fm "L.TA" // 采用期初总资产标准化

gen Qindex = 0.18*cflow + 0.16*invt + 0.17*igr + 0.11*a001101000/`fm' ///

 - 0.11*(TD/a003000000) + 0.12*(div_cash*nshrn)/`fm' ///

 + 0.15*f010701b

label var Qindex "融资约束度量Q指数"

*----------------

*-资产负债率离群值的处理

sum tl , detail

count if tl > 1

drop if tl > 1 //trim 处理

*replace tl = 1 if tl > 1 //winsor 处理

*----------------

*-M&A (兼并收购)的考虑

des tagr

sum tagr, detail

*histogram tagr

count if tagr > 1.5

drop if (tagr > 1.5) & (tagr != .)

*----------------

*-给核心变量添加中文标签

label variable invt "投资支出"

label variable cflow "经营性现金流与总资产之比1"

label variable cflow2 "经营性现金流与总资产之比2"

label variable sale "主营业务收入"

label variable cash "现金存量"

label variable wcmi "(营运资本-存货)/总资产"

label variable roa "总资产收益率"

label variable roe "净资产收益率"

label variable age "企业成立年龄的自然对数"

label variable firmage "企业成立年龄"

label variable pfirmage "企业上市年龄"

*-------------

*-连续型变量 winsorize处理

winsor2 invt cflow tobin cash sale wcmi size choldings cflow2 , replace label // 默认cuts(1 99)

*===模型估计===*

对投资-现金流敏感性(FHP模型)与现金-现金流敏感性(ACW模型)的估计

preserve

xtset id year

xi: reg invt cflow tobin cash sale wcmi size age i.indus i.year , vce(robust)

est store fhp

xi: reg choldings cflow2 tobin size age invt sale wcmi i.indus i.year , vce(robust)

est store acw

esttab fhp acw , mtitle("fhp" "acw") b(%6.3f) t(%6.2f) ///

nogaps compress drop(*year* *indus*) ///

star(* 0.1 ** 0.05 *** 0.01) s(N F r2_a) ///

order(_cons cflow cflow2 tobin cash sale wcmi size age invt)

restore

对投资-现金流敏感性模型（FHP模型）与现金-现金流敏感性模型（ACW模型）的估计结果如下：

本文采用的原始数据和do文档将会在会计学术联盟举办的“实证会计与Stata应用技能训练营02期”期间进行推文公布。如果盟友还想学习更多的实证会计研究变量的Stata编程技术，请盟友们持续关注我们的训练营（报名链接：点击下方阅读原文奥！）。

自7月18日开始，训练营将进行高级应用模块的直播，想要学习实证会计变量Stata编程方法的盟友们，快快报名学习吧！

点击上方图片，

了解最新实证会计与Stata应用训练营！

本期的Stata推文就是这些，希望能给各位盟友带来一些帮助。如果您觉得推文不错，请您记得留言或点赞哦！

如果还有没解决的问题，没关系，可以及时给我们留言哦，或加入我们的社群！

推荐阅读：

素材提供｜Stata服务部

执行编辑丨中山大学南方学院 姚懿轩

执行编辑丨吉林建筑大学 暴庭玮

终审 | 西北师范大学  杨阳

主编｜北京交通大学会计系  水皮（李高波）

欢迎大家分享和转发朋友圈

推荐阅读

学者关注：

学术研讨会：

求职广角：

聚焦训练营：

聚焦会计生态圈：

投稿或合作，请联系微信：610997158

阅读原文，训练营可报名哦~